Heimseite
Seitenübersicht
An/abmeldung
Anschlagbrett
Herunterladen(c) 2005-2024 XLOG Technologies AG
/**
* Modern Albufeira Prolog Interpreter
*
* Warranty & Liability
* To the extent permitted by applicable law and unless explicitly
* otherwise agreed upon, XLOG Technologies AG makes no warranties
* regarding the provided information. XLOG Technologies AG assumes
* no liability that any problems might be solved with the information
* provided by XLOG Technologies AG.
*
* Rights & License
* All industrial property rights regarding the information - copyright
* and patent rights in particular - are the sole property of XLOG
* Technologies AG. If the company was not the originator of some
* excerpts, XLOG Technologies AG has at least obtained the right to
* reproduce, change and translate the information.
*
* Reproduction is restricted to the whole unaltered document. Reproduction
* of the information is only allowed for non-commercial uses. Selling,
* giving away or letting of the execution of the library is prohibited.
* The library can be distributed as part of your applications and libraries
* for execution provided this comment remains unchanged.
*
* Restrictions
* Only to be distributed with programs that add significant and primary
* functionality to the library. Not to be distributed with additional
* software intended to replace any components of the library.
*
* Trademarks
* Jekejeke is a registered trademark of XLOG Technologies AG.
*/
/*******************************************************************/
/* Bundler Python */
/*******************************************************************/
/**
* bundlepy_add(A, B):
* bundlepy_add(A, B, O):
* The predicate succeeds in appending the Python files
* A to the Python file B, converting Python to
* common Python. The bundler silently extends an already
* existing Python file B. The ternary predicate allows
* specifying bundle options.
*/
% bundlepy_add(+Atom, +Atom)
bundlepy_add(InName, OutName) :-
bundlepy_add(InName, OutName, []).
% bundlepy_add(+Atom, +Atom, +List)
bundlepy_add(InName, OutName, Opt) :-
decode_bundlepy_opts(Opt, 0, Flags),
setup_once_cleanup(
open(OutName, append, OutStream),
bundlepy_file(InName, OutStream, Flags),
close(OutStream)).
/**
* bundlepy_file(A, S, F):
* Copy the file A into the stream S, converting Python
* to Python determined by the flags F.
*/
% bundlepy_file(+Atom, +Stream, +Integer)
bundlepy_file(InName, OutStream, Flags) :-
setup_once_cleanup(
open(InName, read, InStream),
sys_bundlepy_lines(InStream, OutStream, Flags),
close(InStream)).
% sys_bundlepy_lines(+Stream, +Stream, +Integer)
sys_bundlepy_lines(InStream, OutStream, Flags) :-
repeat,
get_atom(InStream, 0'\n, Line),
(Line \== '' ->
sys_bundlepy_line(Line, Line2, InStream, Flags),
write(OutStream, Line2), fail; !).
% sys_bundlepy_line(+Atom, -Atom, +Stream, +Integer)
sys_bundlepy_line(Line, _, _, _) :-
atom_concat('#', _, Line), !, fail.
sys_bundlepy_line(Line, Line2, InStream, Flags) :-
strip_qualified(M),
sub_atom(Line, Pos, _, Pos2, M), !,
sub_atom(Line, 0, Pos, _, A),
sub_atom(Line, _, Pos2, 0, B),
atom_concat(A, B, Line3),
sys_bundlepy_line(Line3, Line2, InStream, Flags).
sys_bundlepy_line(Line, _, _, _) :-
atom_concat('import ', H, Line),
atom_concat(M, '\n', H),
strip_qualified2(M), !, fail.
sys_bundlepy_line(Line, _, _, _) :-
atom_concat('import ', H, Line),
sub_atom(H, Pos, _, _, ' as '),
sub_atom(H, 0, Pos, _, M),
strip_qualified2(M), !, fail.
sys_bundlepy_line(Line, Line2, _, _) :-
atom_concat('from dogelog ', A, Line), !,
atom_concat('from __main__ ', A, Line2).
/* import handling */
sys_bundlepy_line(Line, _, InStream, Flags) :- Flags /\ 4 =:= 0,
atom_concat('from ', H, Line),
sub_atom(H, Pos, _, _, ' import ('),
sub_atom(H, 0, Pos, _, M),
strip_qualified2(M), !,
(Line2 = Line; enum_lines(InStream, Line2)),
atom_concat(_, ')\n', Line2), !, fail.
sys_bundlepy_line(Line, _, _, Flags) :- Flags /\ 4 =:= 0,
atom_concat('from ', H, Line),
sub_atom(H, Pos, _, _, ' import '),
sub_atom(H, 0, Pos, _, M),
strip_qualified2(M), !, fail.
sys_bundlepy_line(Line, Line, _, _).
/*******************************************************************/
/* Dogelog Database */
/*******************************************************************/
% strip_qualified(-Atom)
strip_qualified('store.').
strip_qualified('machine.').
strip_qualified('special.').
strip_qualified('runtime.').
strip_qualified('eval.').
strip_qualified('unicode.').
strip_qualified('bootload.').
strip_qualified('streams.').
% strip_qualified2(-Atom)
strip_qualified2('nova.store').
strip_qualified2('nova.machine').
strip_qualified2('nova.special').
strip_qualified2('nova.runtime').
strip_qualified2('nova.eval').
strip_qualified2('nova.unicode').
strip_qualified2('bootload').
strip_qualified2('streams').
/*******************************************************************/
/* Decode Bundle Python Options */
/*******************************************************************/
% decode_bundlepy_opts(+List, +Integer, -Integer)
decode_bundlepy_opts(V, _, _) :- var(V),
throw(error(instantiation_error,_)).
decode_bundlepy_opts([X|L], I, O) :- !,
decode_bundlepy_opt(X, I, H),
decode_bundlepy_opts(L, H, O).
decode_bundlepy_opts([], H, H) :- !.
decode_bundlepy_opts(L, _, _) :-
throw(error(type_error(list,L),_)).
% decode_bundlepy_opt(+Option, +Triple, -Triple)
decode_bundlepy_opt(V, _, _) :- var(V),
throw(error(instantiation_error,_)).
decode_bundlepy_opt(keep_import(B), F, G) :- !,
sys_opt_boolean(B, 4, F, G).
decode_bundlepy_opt(O, _, _) :-
throw(error(type_error(bundlepy_option,O),_)).