Home Page
Site Map
Login/out
Message Board
Download(c) 2005-2025 XLOG Technologies AG
/**
* Warranty & Liability
* To the extent permitted by applicable law and unless explicitly
* otherwise agreed upon, XLOG Technologies AG makes no warranties
* regarding the provided information. XLOG Technologies AG assumes
* no liability that any problems might be solved with the information
* provided by XLOG Technologies AG.
*
* Rights & License
* All industrial property rights regarding the information - copyright
* and patent rights in particular - are the sole property of XLOG
* Technologies AG. If the company was not the originator of some
* excerpts, XLOG Technologies AG has at least obtained the right to
* reproduce, change and translate the information.
*
* Reproduction is restricted to the whole unaltered document. Reproduction
* of the information is only allowed for non-commercial uses. Selling,
* giving away or letting of the execution of the library is prohibited.
* The library can be distributed as part of your applications and libraries
* for execution provided this comment remains unchanged.
*
* Restrictions
* Only to be distributed with programs that add significant and primary
* functionality to the library. Not to be distributed with additional
* software intended to replace any components of the library.
*
* Trademarks
* Jekejeke is a registered trademark of XLOG Technologies AG.
*/
/**
* list_to_set(L, S):
* The predicate succeeds in S with the deduplication of L.
*/
% list_to_set(+List, -List)
list_to_set(L, R) :-
sys_list_to_set(L, [], R).
% sys_list_to_set(+List, +List, -List)
sys_list_to_set([], _, []).
sys_list_to_set([X|L], R, H) :-
member(X, R), !,
sys_list_to_set(L, R, H).
sys_list_to_set([X|L], R, [X|H]) :-
sys_list_to_set(L, [X|R], H).
/**
* subtract(S, T, R):
* The predicate succeeds in R with the subtract of S by T.
*/
% subtract(+List, +List, -List)
subtract([], _, []).
subtract([X|L], R, T) :- member(X, R), !,
subtract(L, R, T).
subtract([X|L], R, [X|S]) :-
subtract(L, R, S).
/**
* intersection(S, T, R):
* The predicate succeeds in R with the intersection of S and T.
*/
% intersection(+List, +List, -List)
intersection([], _, []).
intersection([X|L], R, T) :- member(X, R), !,
T = [X|S],
intersection(L, R, S).
intersection([_|L], R, S) :-
intersection(L, R, S).
/**
* union(S, T, R):
* The predicate succeeds in R with the union of S and T.
*/
% union(+List, +List, -List)
union(L, R, S) :-
subtract(R, L, H),
append(L, H, S).
/**
* symdiff(S, T, R):
* The predicate succeeds in R with the symmetric subtract of S and T.
*/
% symdiff(+List, +List, -List)
symdiff(L, R, S) :-
subtract(L, R, H),
subtract(R, L, J),
append(H, J, S).
/*******************************************************************/
/* Set Tests */
/*******************************************************************/
/**
* subset(S, T):
* The predicate succeeds when S is a subset of T.
*/
% subset(+List, +List)
subset([], _).
subset([X|Y], Z) :- member(X, Z), !,
subset(Y, Z).
/**
* disjoint(S, T):
* The predicate succeeds when S is disjoint to T.
*/
% disjoint(+List, +List)
disjoint([], _).
disjoint([X|_], Z) :- member(X, Z), !, fail.
disjoint([_|Y], Z) :-
disjoint(Y, Z).
/**
* equal(S, T):
* The predicate succeeds when S is equal to T.
*/
% equal(+List, +List)
equal(L, R) :-
subset(L, R),
subset(R, L).