Prolog "compat"

         
/**
* Warranty & Liability
* To the extent permitted by applicable law and unless explicitly
* otherwise agreed upon, XLOG Technologies AG makes no warranties
* regarding the provided information. XLOG Technologies AG assumes
* no liability that any problems might be solved with the information
* provided by XLOG Technologies AG.
*
* Rights & License
* All industrial property rights regarding the information - copyright
* and patent rights in particular - are the sole property of XLOG
* Technologies AG. If the company was not the originator of some
* excerpts, XLOG Technologies AG has at least obtained the right to
* reproduce, change and translate the information.
*
* Reproduction is restricted to the whole unaltered document. Reproduction
* of the information is only allowed for non-commercial uses. Selling,
* giving away or letting of the execution of the library is prohibited.
* The library can be distributed as part of your applications and libraries
* for execution provided this comment remains unchanged.
*
* Restrictions
* Only to be distributed with programs that add significant and primary
* functionality to the library. Not to be distributed with additional
* software intended to replace any components of the library.
*
* Trademarks
* Jekejeke is a registered trademark of XLOG Technologies AG.
*/
% sys_meta_args(+Atom, +Integer, -List)
:- multifile(sys_meta_args/3).
% control flow
sys_meta_args(forall, 2, [g,g]).
sys_meta_args(try_call_finally, 3, [g,g,g]).
sys_meta_args(undo, 1, [g]).
sys_meta_args(setup_undo, 2, [g,g]).
/**
* forall(A, B): [N208 8.10.4]
* The predicate succeeds when there is no success of A
* such that B fails. Otherwise, the predicate fails.
*/
% forall(+Goal, +Goal)
forall(A, B) :- \+ (A, \+ B).
/**
* try_call_finally(S, G, C):
* The predicate succeeds whenever G succeeds. The goal S is
* called for the call and redo port. The goal C is called for
* the exit, fail and error port.
*/
% try_call_finally(+Goal, +Goal, +Goal)
try_call_finally(S, G, C) :-
current_prolog_flag(async_mode, on), !,
shield(sys_try_call_finally(S, unshield(G), suppress(C))).
try_call_finally(S, G, C) :-
sys_try_call_finally(S, G, suppress(C)).
% sys_try_call_finally(+Goal, +Goal, +Goal)
sys_try_call_finally(S, G, C) :-
(S; C, fail),
'$MARK'(X),
sys_trap(G, E, (C, os_raise(E))),
'$MARK'(Y),
(X == Y -> !, C; (C; S, fail)).
/****************************************************************/
/* Trailed Changes */
/****************************************************************/
/**
* set_arg(K, X, Y):
* Same as change_arg/3, but the change is undone upon backtracking.
*/
% set_arg(+Integer, +Callable, +Term)
set_arg(N, C, A) :-
arg(N, C, B),
ir_trail_undo(change_arg(N, C, B)),
change_arg(N, C, A).
/**
* undo(U):
* The predicate succeeds. The goal U is called
* for the redo port of the last goal with redo port.
*/
% undo(+Goal)
undo(U) :-
ir_trail_undo(suppress(U)).
/**
* setup_undo(S, U):
* The predicate succeeds whenever S succeeds. The goal U is
* called for the redo port of the last goal with redo port.
*/
% setup_undo(+Goal, +Goal)
setup_undo(S, U) :-
current_prolog_flag(async_mode, on), !,
shield(sys_setup_undo(S, suppress(U))).
setup_undo(S, U) :-
sys_setup_undo(S, suppress(U)).
% sys_setup_undo(+Goal, +Goal)
sys_setup_undo(S, U) :-
S,
ir_trail_undo(U).
/*******************************************************************/
/* Foreign Predicates */
/*******************************************************************/
% term_singletons(X, Y): [N208 8.2.4]
% defined in foreign(fastlib)
% ground(T): [TC2 8.3.10]
% defined in foreign(fastlib)
% nonground(T, V):
% defined in foreign(fastlib)
% divmod(X, Y, Z, T):
% no good support in JavaScript, hopefully this will change
% defined in foreign(fastlib)
% gcd(X, Y):
% no good support in JavaScript, hopefully this will change
% defined in foreign(fastlib)
% ir_trail_undo(X):
% defined in foreign(fastlib)
:- ensure_loaded(foreign(fastlib)).